利用電位計替代旋轉(zhuǎn)開關(guān)設(shè)計方案

　　有時，基于微控制器的產(chǎn)品需要使用旋轉(zhuǎn)開關(guān)。由于很多微控制器都內(nèi)置了ADC,在找不到旋轉(zhuǎn)開關(guān)或旋轉(zhuǎn)開關(guān)價格過高時，可以使用低成本電位計來替代旋轉(zhuǎn)開關(guān)(圖1)。

　　盡管僅需執(zhí)行少量指令即可將電位計設(shè)定值數(shù)字化，使其表現(xiàn)得像開關(guān)一樣，但一個急需解決的問題是，在電氣噪聲或機(jī)械噪聲的影響下，在某一個值和下一個值之間的切換閾值處，數(shù)值會不穩(wěn)定。該問題的解決方法是為每次轉(zhuǎn)換引入上、下兩個遲滯閾值，這樣一來，電位計就需要在另一個開關(guān)狀態(tài)有效前越過閾值。針對每次更新的開關(guān)狀態(tài)，都會有新的一對閾值替換之前的閾值。如此，遲滯效應(yīng)可以實(shí)現(xiàn)各狀態(tài)間的完全切換。

　　圖1:替代多擲開關(guān)

　　這一方法具有下述諸多優(yōu)勢：單端口引腳對旋轉(zhuǎn)開關(guān)的多端口引腳、成本低、更易獲得且可實(shí)現(xiàn)去抖動切換。該方法的不足之處在于會失去制動感。設(shè)定點(diǎn)的另一特性是其可設(shè)置在任一位置，例如用以補(bǔ)償電位計在響應(yīng)過程中出現(xiàn)的非線性變化。

　　遲滯通常稍高于會導(dǎo)致不期望切換的任何噪聲。建議在電位計觸點(diǎn)與地之間設(shè)置一個電容器，以濾除觸點(diǎn)噪聲(圖1)。

　　圖2列出了算法。一旦用ADC對電位計設(shè)定值進(jìn)行了數(shù)字化操作，該數(shù)值就將與下閾值比較，若低于下閾值，開關(guān)狀態(tài)會逐漸降低并限制至零。若電位計設(shè)定值高于上閾值，開關(guān)狀態(tài)會逐漸增大并限制至最大值。若開關(guān)狀態(tài)發(fā)生變化，則上、下閾值會進(jìn)行更新，并終止子程序。

　　圖2:流程圖

　　為確保該遲滯算法起作用，必須定期讀取電位計設(shè)定值，并與上一次開關(guān)狀態(tài)進(jìn)行比較。這樣做旨在將從不同狀態(tài)跨過閾值或處于相同值的電位計設(shè)定值與相同狀態(tài)區(qū)分開。

　　此處還需要計算出采樣率的最小值，可由電位計旋轉(zhuǎn)率最大值除以開關(guān)狀態(tài)數(shù)得到。例如，假設(shè)單匝電位計旋鈕在0.25s內(nèi)完整旋轉(zhuǎn)一圈，同時假定有七種狀態(tài)，那么最低掃描率為28Hz.若電位計數(shù)值采樣周期低于最小值，即使切換方向正確，計算得出的開關(guān)狀態(tài)也可能不正確。倘若未以較快的速率持續(xù)改變電位計設(shè)定值，則隨后的采樣會對切換狀態(tài)進(jìn)行校正。

　　以七種開關(guān)狀態(tài)為例創(chuàng)建一個閾值列表。假設(shè)有一個8位ADC。首先，ADC的256步范圍被分割為七種開關(guān)狀態(tài)。各開關(guān)狀態(tài)的寬度為ADC范圍除以狀態(tài)數(shù)，即：256/7=36.6.對其四舍五入，將各狀態(tài)的寬度定為36，但是兩個外端狀態(tài)需增加至38，以使總寬度為256。

　　下一步是確定各開關(guān)狀態(tài)的邊界。對于狀態(tài)0,邊界為0~37(包含兩端)。狀態(tài)1從38開始到73結(jié)束，其余開關(guān)狀態(tài)依此類推。根據(jù)增加或降低至邊界的遲滯數(shù)值確定閾值。此處使用4這一遲滯值。遲滯量既不得大于寬度，也不得低于預(yù)期的噪聲。因此，上邊界加4即可得出上閾值，下邊界減4即可得出下閾值，如表1所示。從該例可發(fā)現(xiàn)，從狀態(tài)2切換為狀態(tài)1需要使電位計數(shù)值下降至比切換點(diǎn)數(shù)值74小4，因此下閾值為70。相反，從狀態(tài)1切換為狀態(tài)2需要使電位計數(shù)值上升至比切換點(diǎn)數(shù)值73高4，因此上限閾值為77。用于程序代碼的表格僅需標(biāo)明上、下閾值，在此例中僅需14個字節(jié)。

　　表1 閾值

　　代碼示例(見下)支持Silicon Labs的C8051F310(8051架構(gòu))，但也可以很容易地改編用于其他微控制器。

　　;POT2SW INITIALIZATION

　　MOV UPRVAL, #00H;set upper value to opposite end to force the code to run

　　MOV LWRVAL, #0FFH;set lower value to opposite end to force the code to run

　　MOV SWPOS, #03H;initialize switch position to middle

　　MOV POSMAX, #06H;set maximum SWITCH position value

　　;SUBROUTINES

　　POT2SW:;CALCULATE SWITCH POSITION VALUE FROM POTENTIOMETER VALUE IN ACC

　　;check if pot setting is below lower threshold

　　CLR C

　　MOV B, A ;save pot setting to register B

　　SUBB A, LWRVAL;potval - lwrval

　　JNC P2S1 ;no carry means potval >= lwrval

　　DEC SWPOS ;carry means potval < lwrval, so decrement switch position value

　　;check if switch position is < zero

　　MOV A, POSMAX;load maximum switch position value

　　CLR C

　　SUBB A, SWPOS;max switch value - switch position

　　JNC P2S2

　　MOV SWPOS, #00H;reset switch position value to zero since underflow

　　SJMP P2S2

　　P2S1: ;check if pot setting is above upper theshold

　　CLR C

　　MOV A, UPRVAL

　　SUBB A, B ;uprval - potval

　　JNC P2S2 ;no carry means potval <= uprval

　　INC SWPOS ;carry means potval >uprval, so increment switch position value

　　;check if switch position is > max

　　MOV A, POSMAX;load maximum xwitch position value

　　CLR C

　　SUBB A, SWPOS

　　JNC P2S2

　　MOV SWPOS, POSMAX;reset curve number to max curve value since overflow

　　P2S2: ;read lower and upper thresholds using switch position value

　　MOV A, SWPOS ;multiply switch position value by 2

　　MOV B, #02H

　　MUL AB

　　MOV B, A ;save multiplied value as table offset

　　MOV DPTR, #HYSTBL;load base address of table pointer

　　MOVC A, @A+DPTR;look up table value from base address + offset

　　MOV LWRVAL, A;read lower threshold value

　　MOV A, B

　　INC DPTR ;increment base address

　　MOVC A, @A+DPTR

　　MOV UPRVAL, A;read upper threshold value

　　RET

　　HYSTBL:;TABLE OF LOWER & UPPER THRESHOLDS FOR SEVEN POSITION SWITCH

　　DB00D,41D;Switch state 0

　　DB34D,77D;Switch state 1

　　DB70D,113D;Switch state 2

　　DB106D,149D;Switch state 3

　　DB142D,185D;Switch state 4

　　DB178D,221D;Switch state 5

　　DB214D,255D;Switch state 6