ARM應(yīng)用系統(tǒng)開發(fā)詳解 第4章 ARM程序設(shè)計基礎(chǔ)
加入技術(shù)交流群
本章的主要內(nèi)容：
－ ARM編譯器所支持的偽指令
－ 匯編語言的語句格式
－ 匯編語言的程序結(jié)構(gòu)
－ 相關(guān)的程序示例
4.1 ARM匯編器所支持的偽指令
在ARM匯編語言程序里，有一些特殊指令助記符，這些助記符與指令系統(tǒng)的助記符不同，沒有相對應(yīng)的操作碼，通常稱這些特殊指令助記符為偽指令，他們所完成的操作稱為偽操作。偽指令在源程序中的作用是為完成匯編程序作各種準(zhǔn)備工作的，這些偽指令僅在匯編過程中起作用，一旦匯編結(jié)束，偽指令的使命就完成。
在ARM的匯編程序中，有如下幾種偽指令：符號定義偽指令、數(shù)據(jù)定義偽指令、匯編控制偽指令、宏指令以及其他偽指令。
4.1.1符號定義（Symbol Definition）偽指令
符號定義偽指令用于定義ARM匯編程序中的變量、對變量賦值以及定義寄存器的別名等操作。常見的符號定義偽指令有如下幾種：
— 用于定義全局變量的GBLA、GBLL和GBLS。
— 用于定義局部變量的LCLA、LCLL和LCLS。
— 用于對變量賦值的SETA、SETL、SETS。
— 為通用寄存器列表定義名稱的RLIST。
1、 GBLA、GBLL和GBLS
語法格式：
GBLA（GBLL或GBLS） 全局變量名
GBLA、GBLL和GBLS偽指令用于定義一個ARM程序中的全局變量，并將其初始化。其中：
GBLA偽指令用于定義一個全局的數(shù)字變量，并初始化為0；
GBLL偽指令用于定義一個全局的邏輯變量，并初始化為F（假）；
GBLS偽指令用于定義一個全局的字符串變量，并初始化為空；
由于以上三條偽指令用于定義全局變量，因此在整個程序范圍內(nèi)變量名必須唯一。
使用示例：
GBLA Test1 ；定義一個全局的數(shù)字變量，變量名為Test1
Test1 SETA 0xaa ；將該變量賦值為0xaa
GBLL Test2 ；定義一個全局的邏輯變量，變量名為Test2
Test2 SETL {TRUE} ；將該變量賦值為真
GBLS Test3 ；定義一個全局的字符串變量，變量名為Test3
Test3 SETS “Testing” ；將該變量賦值為“Testing”
2、 LCLA、LCLL和LCLS
語法格式：
LCLA（LCLL或LCLS） 局部變量名
LCLA、LCLL和LCLS偽指令用于定義一個ARM程序中的局部變量，并將其初始化。其中：
LCLA偽指令用于定義一個局部的數(shù)字變量，并初始化為0；
LCLL偽指令用于定義一個局部的邏輯變量，并初始化為F（假）；
LCLS偽指令用于定義一個局部的字符串變量，并初始化為空；
以上三條偽指令用于聲明局部變量，在其作用范圍內(nèi)變量名必須唯一。
使用示例：
LCLA Test4 ；聲明一個局部的數(shù)字變量，變量名為Test4
Test3 SETA 0xaa ；將該變量賦值為0xaa
LCLL Test5 ；聲明一個局部的邏輯變量，變量名為Test5
Test4 SETL {TRUE} ；將該變量賦值為真
LCLS Test6 ；定義一個局部的字符串變量，變量名為Test6
Test6 SETS “Testing” ；將該變量賦值為“Testing”
3、 SETA、SETL和SETS
語法格式：
變量名 SETA（SETL或SETS） 表達(dá)式
偽指令SETA、SETL、SETS用于給一個已經(jīng)定義的全局變量或局部變量賦值。
SETA偽指令用于給一個數(shù)學(xué)變量賦值；
SETL偽指令用于給一個邏輯變量賦值；
SETS偽指令用于給一個字符串變量賦值；
其中，變量名為已經(jīng)定義過的全局變量或局部變量，表達(dá)式為將要賦給變量的值。
使用示例：
LCLA Test3 ；聲明一個局部的數(shù)字變量，變量名為Test3
Test3 SETA 0xaa ；將該變量賦值為0xaa
LCLL Test4 ；聲明一個局部的邏輯變量，變量名為Test4
Test4 SETL {TRUE} ；將該變量賦值為真
4、 RLIST
語法格式：
名稱 RLIST {寄存器列表}
RLIST偽指令可用于對一個通用寄存器列表定義名稱，使用該偽指令定義的名稱可在ARM指令LDM/STM中使用。在LDM/STM指令中，列表中的寄存器訪問次序為根據(jù)寄存器的編號由低到高，而與列表中的寄存器排列次序無關(guān)。
使用示例：
RegList RLIST {R0-R5，R8，R10} ；將寄存器列表名稱定義為RegList，可在ARM指令LDM/STM中通過該名稱訪問寄存器列表。
4.1.2數(shù)據(jù)定義（Data Definition）偽指令
數(shù)據(jù)定義偽指令一般用于為特定的數(shù)據(jù)分配存儲單元，同時可完成已分配存儲單元的初始化。常見的數(shù)據(jù)定義偽指令有如下幾種：
— DCB 用于分配一片連續(xù)的字節(jié)存儲單元并用指定的數(shù)據(jù)初始化。
— DCW（DCWU） 用于分配一片連續(xù)的半字存儲單元并用指定的數(shù)據(jù)初始化。
— DCD（DCDU） 用于分配一片連續(xù)的字存儲單元并用指定的數(shù)據(jù)初始化。
— DCFD（DCFDU）用于為雙精度的浮點數(shù)分配一片連續(xù)的字存儲單元并用指定的數(shù)據(jù)初始化。
— DCFS（DCFSU） 用于為單精度的浮點數(shù)分配一片連續(xù)的字存儲單元并用指定的數(shù)據(jù)初始化。
— DCQ（DCQU） 用于分配一片以8字節(jié)為單位的連 續(xù)的存儲單元并用指定的數(shù)據(jù)初始化。
— SPACE 用于分配一片連續(xù)的存儲單元
— MAP 用于定義一個結(jié)構(gòu)化的內(nèi)存表首地址
— FIELD 用于定義一個結(jié)構(gòu)化的內(nèi)存表的數(shù)據(jù)域
1、 DCB
語法格式：
標(biāo)號 DCB 表達(dá)式
DCB偽指令用于分配一片連續(xù)的字節(jié)存儲單元并用偽指令中指定的表達(dá)式初始化。其中，表達(dá)式可以為0～255的數(shù)字或字符串。DCB也可用“=”代替。
使用示例：
Str DCB “This is a test！” ；分配一片連續(xù)的字節(jié)存儲單元并初始化。
2、 DCW（或DCWU）
語法格式：
標(biāo)號 DCW（或DCWU） 表達(dá)式
DCW（或DCWU）偽指令用于分配一片連續(xù)的半字存儲單元并用偽指令中指定的表達(dá)式初始化。其中，表達(dá)式可以為程序標(biāo)號或數(shù)字表達(dá)式。。
用DCW分配的字存儲單元是半字對齊的，而用DCWU分配的字存儲單元并不嚴(yán)格半字對齊。
使用示例：
DataTest DCW 1，2，3 ；分配一片連續(xù)的半字存儲單元并初始化。
3、 DCD（或DCDU）
語法格式：
標(biāo)號 DCD（或DCDU） 表達(dá)式
DCD（或DCDU）偽指令用于分配一片連續(xù)的字存儲單元并用偽指令中指定的表達(dá)式初始化。其中，表達(dá)式可以為程序標(biāo)號或數(shù)字表達(dá)式。DCD也可用“&”代替。
用DCD分配的字存儲單元是字對齊的，而用DCDU分配的字存儲單元并不嚴(yán)格字對齊。
使用示例：
DataTest DCD 4，5，6 ；分配一片連續(xù)的字存儲單元并初始化。
4、 DCFD（或DCFDU）
語法格式：
標(biāo)號 DCFD（或DCFDU） 表達(dá)式
DCFD（或DCFDU）偽指令用于為雙精度的浮點數(shù)分配一片連續(xù)的字存儲單元并用偽指令中指定的表達(dá)式初始化。每個雙精度的浮點數(shù)占據(jù)兩個字單元。
用DCFD分配的字存儲單元是字對齊的，而用DCFDU分配的字存儲單元并不嚴(yán)格字對齊。
使用示例：
FDataTest DCFD 2E115，-5E7 ；分配一片連續(xù)的字存儲單元并初始化為指定的雙精度數(shù)。
5、 DCFS（或DCFSU）
語法格式：
標(biāo)號 DCFS（或DCFSU） 表達(dá)式
DCFS（或DCFSU）偽指令用于為單精度的浮點數(shù)分配一片連續(xù)的字存儲單元并用偽指令中指定的表達(dá)式初始化。每個單精度的浮點數(shù)占據(jù)一個字單元。
用DCFS分配的字存儲單元是字對齊的，而用DCFSU分配的字存儲單元并不嚴(yán)格字對齊。
使用示例：
FDataTest DCFS 2E5，-5E－7 ；分配一片連續(xù)的字存儲單元并初始化為指定的單精度數(shù)。
6、 DCQ(或DCQU）
語法格式：
標(biāo)號 DCQ（或DCQU） 表達(dá)式
DCQ（或DCQU）偽指令用于分配一片以8個字節(jié)為單位的連續(xù)存儲區(qū)域并用偽指令中指定的表達(dá)式初始化。
用DCQ分配的存儲單元是字對齊的，而用DCQU分配的存儲單元并不嚴(yán)格字對齊。
使用示例：
DataTest DCQ 100 ；分配一片連續(xù)的存儲單元并初始化為指定的值。
7、 SPACE
語法格式：
標(biāo)號 SPACE 表達(dá)式
SPACE偽指令用于分配一片連續(xù)的存儲區(qū)域并初始化為0。其中，表達(dá)式為要分配的字節(jié)數(shù)。SPACE也可用“％”代替。
使用示例：
DataSpace SPACE 100 ；分配連續(xù)100字節(jié)的存儲單元并初始化為0。
8、 MAP
語法格式：
MAP 表達(dá)式{，基址寄存器}
MAP偽指令用于定義一個結(jié)構(gòu)化的內(nèi)存表的首地址。MAP也可用“＾”代替。
表達(dá)式可以為程序中的標(biāo)號或數(shù)學(xué)表達(dá)式，基址寄存器為可選項，當(dāng)基址寄存器選項不存在時，表達(dá)式的值即為內(nèi)存表的首地址，當(dāng)該選項存在時，內(nèi)存表的首地址為表達(dá)式的值與基址寄存器的和。
MAP偽指令通常與FIELD偽指令配合使用來定義結(jié)構(gòu)化的內(nèi)存表。
使用示例：
MAP 0x100，R0 ；定義結(jié)構(gòu)化內(nèi)存表首地址的值為0x100＋R0。
9、 FILED
語法格式：
標(biāo)號 FIELD 表達(dá)式
FIELD偽指令用于定義一個結(jié)構(gòu)化內(nèi)存表中的數(shù)據(jù)域。FILED也可用“#”代替。
表達(dá)式的值為當(dāng)前數(shù)據(jù)域在內(nèi)存表中所占的字節(jié)數(shù)。
FIELD偽指令常與MAP偽指令配合使用來定義結(jié)構(gòu)化的內(nèi)存表。MAP偽指令定義內(nèi)存表的首地址，F(xiàn)IELD偽指令定義內(nèi)存表中的各個數(shù)據(jù)域，并可以為每個數(shù)據(jù)域指定一個標(biāo)號供其他的指令引用。
注意MAP和FIELD偽指令僅用于定義數(shù)據(jù)結(jié)構(gòu)，并不實際分配存儲單元。
使用示例：
MAP 0x100 ；定義結(jié)構(gòu)化內(nèi)存表首地址的值為0x100。
A FIELD 16 ；定義A的長度為16字節(jié)，位置為0x100
B FIELD 32 ；定義B的長度為32字節(jié)，位置為0x110
S FIELD 256 ；定義S的長度為256字節(jié)，位置為0x130
4.1.3匯編控制（Assembly Control）偽指令
匯編控制偽指令用于控制匯編程序的執(zhí)行流程，常用的匯編控制偽指令包括以下幾條：
— IF、ELSE、ENDIF
— WHILE、WEND
— MACRO、MEND
— MEXIT
1、 IF、ELSE、ENDIF
語法格式：
IF 邏輯表達(dá)式
指令序列1
ELSE
指令序列2
ENDIF
IF、ELSE、ENDIF偽指令能根據(jù)條件的成立與否決定是否執(zhí)行某個指令序列。當(dāng)IF后面的邏輯表達(dá)式為真，則執(zhí)行指令序列1，否則執(zhí)行指令序列2。其中，ELSE及指令序列2可以沒有，此時，當(dāng)IF后面的邏輯表達(dá)式為真，則執(zhí)行指令序列1，否則繼續(xù)執(zhí)行后面的指令。
IF、ELSE、ENDIF偽指令可以嵌套使用。
使用示例：
GBLL Test ；聲明一個全局的邏輯變量，變量名為Test
……
IF Test = TRUE
指令序列1
ELSE
指令序列2
ENDIF
2、 WHILE、WEND
語法格式：
WHILE 邏輯表達(dá)式
指令序列
WEND
WHILE、WEND偽指令能根據(jù)條件的成立與否決定是否循環(huán)執(zhí)行某個指令序列。當(dāng)WHILE后面的邏輯表達(dá)式為真，則執(zhí)行指令序列，該指令序列執(zhí)行完畢后，再判斷邏輯表達(dá)式的值，若為真則繼續(xù)執(zhí)行，一直到邏輯表達(dá)式的值為假。
WHILE、WEND偽指令可以嵌套使用。
使用示例：
GBLA Counter ；聲明一個全局的數(shù)學(xué)變量，變量名為Counter
Counter SETA 3 ；由變量Counter控制循環(huán)次數(shù)
……
WHILE Counter < 10
指令序列
WEND
3、 MACRO、MEND
語法格式：
$標(biāo)號 宏名 $參數(shù)1，$參數(shù)2，……
指令序列
MEND
MACRO、MEND偽指令可以將一段代碼定義為一個整體，稱為宏指令，然后就可以在程序中通過宏指令多次調(diào)用該段代碼。其中，$標(biāo)號在宏指令被展開時，標(biāo)號會被替換為用戶定義的符號，
宏指令可以使用一個或多個參數(shù)，當(dāng)宏指令被展開時，這些參數(shù)被相應(yīng)的值替換。
宏指令的使用方式和功能與子程序有些相似，子程序可以提供模塊化的程序設(shè)計、節(jié)省存儲空間并提高運行速度。但在使用子程序結(jié)構(gòu)時需要保護(hù)現(xiàn)場，從而增加了系統(tǒng)的開銷，因此，在代碼較短且需要傳遞的參數(shù)較多時，可以使用宏指令代替子程序。
包含在MACRO和MEND之間的指令序列稱為宏定義體，在宏定義體的第一行應(yīng)聲明宏的原型（包含宏名、所需的參數(shù)），然后就可以在匯編程序中通過宏名來調(diào)用該指令序列。在源程序被編譯時，匯編器將宏調(diào)用展開，用宏定義中的指令序列代替程序中的宏調(diào)用，并將實際參數(shù)的值傳遞給宏定義中的形式參數(shù)。
MACRO、MEND偽指令可以嵌套使用。
4、 MEXIT
語法格式：
MEXIT
MEXIT用于從宏定義中跳轉(zhuǎn)出去。
4.1.4其他常用的偽指令
還有一些其他的偽指令，在匯編程序中經(jīng)常會被使用，包括以下幾條：
— AREA
— ALIGN
— CODE16、CODE32
— ENTRY
— END
— EQU
— EXPORT（或GLOBAL）
— IMPORT
— EXTERN
— GET（或INCLUDE）
— INCBIN
— RN
— ROUT
1、 AREA
語法格式：
AREA 段名 屬性1，屬性2，……
AREA偽指令用于定義一個代碼段或數(shù)據(jù)段。其中，段名若以數(shù)字開頭，則該段名需用“|”括起來，如|1_test|。
屬性字段表示該代碼段（或數(shù)據(jù)段）的相關(guān)屬性，多個屬性用逗號分隔。常用的屬性如下：
— CODE屬性：用于定義代碼段，默認(rèn)為READONLY。
— DATA屬性：用于定義數(shù)據(jù)段，默認(rèn)為READWRITE。
— READONLY屬性：指定本段為只讀，代碼段默認(rèn)為READONLY。
— READWRITE屬性：指定本段為可讀可寫，數(shù)據(jù)段的默認(rèn)屬性為READWRITE。
— ALIGN屬性：使用方式為ALIGN 表達(dá)式。在默認(rèn)時，ELF（可執(zhí)行連接文件）的代碼段和數(shù)據(jù)段是按字對齊的，表達(dá)式的取值范圍為0～31，相應(yīng)的對齊方式為2表達(dá)式次方。
— COMMON屬性：該屬性定義一個通用的段，不包含任何的用戶代碼和數(shù)據(jù)。各源文件中同名的COMMON段共享同一段存儲單元。
一個匯編語言程序至少要包含一個段，當(dāng)程序太長時，也可以將程序分為多個代碼段和數(shù)據(jù)段。
使用示例：
AREA Init，CODE，READONLY
指令序列
；該偽指令定義了一個代碼段，段名為Init，屬性為只讀
2、 ALIGN
語法格式：
ALIGN {表達(dá)式{，偏移量}}
ALIGN偽指令可通過添加填充字節(jié)的方式，使當(dāng)前位置滿足一定的對其方式|。其中，表達(dá)式的值用于指定對齊方式，可能的取值為2的冪，如1、2、4、8、16等。若未指定表達(dá)式，則將當(dāng)前位置對齊到下一個字的位置。偏移量也為一個數(shù)字表達(dá)式，若使用該字段，則當(dāng)前位置的對齊方式為：2的表達(dá)式次冪＋偏移量。
使用示例：
AREA Init，CODE，READONLY，ALIEN＝3 ；指定后面的指令為8字節(jié)對齊。
指令序列
END
3、 CODE16、CODE32
語法格式：
CODE16（或CODE32）
CODE16偽指令通知編譯器，其后的指令序列為16位的Thumb指令。
CODE32偽指令通知編譯器，其后的指令序列為32位的ARM指令。
若在匯編源程序中同時包含ARM指令和Thumb指令時，可用CODE16偽指令通知編譯器其后的指令序列為16位的Thumb指令，CODE32偽指令通知編譯器其后的指令序列為32位的ARM指令。因此，在使用ARM指令和Thumb指令混合編程的代碼里，可用這兩條偽指令進(jìn)行切換，但注意他們只通知編譯器其后指令的類型，并不能對處理器進(jìn)行狀態(tài)的切換。
使用示例：
AREA Init，CODE，READONLY
……
CODE32 ；通知編譯器其后的指令為32位的ARM指令
LDR R0，＝NEXT＋1 ；將跳轉(zhuǎn)地址放入寄存器R0
BX R0 ；程序跳轉(zhuǎn)到新的位置執(zhí)行，并將處理器切換到Thumb工作狀態(tài)
……
CODE16 ；通知編譯器其后的指令為16位的Thumb指令
NEXT LDR R3，＝0x3FF
……
END ；程序結(jié)束
4、 ENTRY
語法格式：
ENTRY
ENTRY偽指令用于指定匯編程序的入口點。在一個完整的匯編程序中至少要有一個ENTRY（也可以有多個，當(dāng)有多個ENTRY時，程序的真正入口點由鏈接器指定），但在一個源文件里最多只能有一個ENTRY（可以沒有）。
使用示例：
AREA Init，CODE，READONLY
ENTRY ；指定應(yīng)用程序的入口點
……
5、 END
語法格式：
END
END偽指令用于通知編譯器已經(jīng)到了源程序的結(jié)尾。
使用示例：
AREA Init，CODE，READONLY
……
END ；指定應(yīng)用程序的結(jié)尾
6、 EQU
語法格式：
名稱 EQU 表達(dá)式{，類型}
EQU偽指令用于為程序中的常量、標(biāo)號等定義一個等效的字符名稱，類似于C語言中的＃define。其中EQU可用“*”代替。
名稱為EQU偽指令定義的字符名稱，當(dāng)表達(dá)式為32位的常量時，可以指定表達(dá)式的數(shù)據(jù)類型，可以有以下三種類型：
CODE16、CODE32和DATA
使用示例：
Test EQU 50 ；定義標(biāo)號Test的值為50
Addr EQU 0x55，CODE32 ；定義Addr的值為0x55，且該處為32位的ARM指令。
7、 EXPORT（或GLOBAL）
語法格式：
EXPORT 標(biāo)號{[WEAK]}
EXPORT偽指令用于在程序中聲明一個全局的標(biāo)號，該標(biāo)號可在其他的文件中引用。EXPORT可用GLOBAL代替。標(biāo)號在程序中區(qū)分大小寫，[WEAK]選項聲明其他的同名標(biāo)號優(yōu)先于該標(biāo)號被引用。
使用示例：
AREA Init，CODE，READONLY
EXPORT Stest ；聲明一個可全局引用的標(biāo)號Stest
……
END
8、 IMPORT
語法格式：
IMPORT 標(biāo)號{[WEAK]}
IMPORT偽指令用于通知編譯器要使用的標(biāo)號在其他的源文件中定義，但要在當(dāng)前源文件中引用，而且無論當(dāng)前源文件是否引用該標(biāo)號，該標(biāo)號均會被加入到當(dāng)前源文件的符號表中。
標(biāo)號在程序中區(qū)分大小寫，[WEAK]選項表示當(dāng)所有的源文件都沒有定義這樣一個標(biāo)號時，編譯器也不給出錯誤信息，在多數(shù)情況下將該標(biāo)號置為0，若該標(biāo)號為B或BL指令引用，則將B或BL指令置為NOP操作。
使用示例：
AREA Init，CODE，READONLY
IMPORT Main ；通知編譯器當(dāng)前文件要引用標(biāo)號Main，但Main在其他源文件中定義
……
END
9、 EXTERN
語法格式：
EXTERN 標(biāo)號{[WEAK]}
EXTERN偽指令用于通知編譯器要使用的標(biāo)號在其他的源文件中定義，但要在當(dāng)前源文件中引用，如果當(dāng)前源文件實際并未引用該標(biāo)號，該標(biāo)號就不會被加入到當(dāng)前源文件的符號表中。
標(biāo)號在程序中區(qū)分大小寫，[WEAK]選項表示當(dāng)所有的源文件都沒有定義這樣一個標(biāo)號時，編譯器也不給出錯誤信息，在多數(shù)情況下將該標(biāo)號置為0，若該標(biāo)號為B或BL指令引用，則將B或BL指令置為NOP操作。
使用示例：
AREA Init，CODE，READONLY
EXTERN Main ；通知編譯器當(dāng)前文件要引用標(biāo)號Main，但Main在其他源文件中定義
……
END
10、 GET（或INCLUDE）
語法格式：
GET 文件名
GET偽指令用于將一個源文件包含到當(dāng)前的源文件中，并將被包含的源文件在當(dāng)前位置進(jìn)行匯編處理?？梢允褂肐NCLUDE代替GET。
匯編程序中常用的方法是在某源文件中定義一些宏指令，用EQU定義常量的符號名稱，用MAP和FIELD定義結(jié)構(gòu)化的數(shù)據(jù)類型，然后用GET偽指令將這個源文件包含到其他的源文件中。使用方法與C語言中的“include”相似。
GET偽指令只能用于包含源文件，包含目標(biāo)文件需要使用INCBIN偽指令
使用示例：
AREA Init，CODE，READONLY
GET a1.s ；通知編譯器當(dāng)前源文件包含源文件a1.s
GE T C：/a2.s ；通知編譯器當(dāng)前源文件包含源文件C：/ a2.s
……
END
11、 INCBIN
語法格式：
INCBIN 文件名
INCBIN偽指令用于將一個目標(biāo)文件或數(shù)據(jù)文件包含到當(dāng)前的源文件中，被包含的文件不作任何變動的存放在當(dāng)前文件中，編譯器從其后開始繼續(xù)處理。
使用示例：
AREA Init，CODE，READONLY
INCBIN a1.dat ；通知編譯器當(dāng)前源文件包含文件a1.dat
INCBIN C：/a2.txt ；通知編譯器當(dāng)前源文件包含文件C：/a2.txt
……
END
12、 RN
語法格式：
名稱 RN 表達(dá)式
RN偽指令用于給一個寄存器定義一個別名。采用這種方式可以方便程序員記憶該寄存器的功能。其中，名稱為給寄存器定義的別名，表達(dá)式為寄存器的編碼。
使用示例：
Temp RN R0 ；將R0定義一個別名Temp
13、 ROUT
語法格式：
{名稱} ROUT
ROUT偽指令用于給一個局部變量定義作用范圍。在程序中未使用該偽指令時，局部變量的作用范圍為所在的AREA，而使用ROUT后，局部變量的作為范圍為當(dāng)前ROUT和下一個ROUT之間。
4.2匯編語言的語句格式
ARM（Thumb）匯編語言的語句格式為：
{標(biāo)號} {指令或偽指令} {；注釋}
在匯編語言程序設(shè)計中，每一條指令的助記符可以全部用大寫、或全部用小寫，但不用許在一條指令中大、小寫混用。
同時，如果一條語句太長，可將該長語句分為若干行來書寫，在行的末尾用“/”表示下一行與本行為同一條語句。
4.2.1在匯編語言程序中常用的符號
在匯編語言程序設(shè)計中，經(jīng)常使用各種符號代替地址、變量和常量等，以增加程序的可讀性。盡管符號的命名由編程者決定，但并不是任意的，必須遵循以下的約定：
— 符號區(qū)分大小寫，同名的大、小寫符號會被編譯器認(rèn)為是兩個不同的符號。
— 符號在其作用范圍內(nèi)必須唯一。
— 自定義的符號名不能與系統(tǒng)的保留字相同。
— 符號名不應(yīng)與指令或偽指令同名。
1、 程序中的變量
程序中的變量是指其值在程序的運行過程中可以改變的量。ARM（Thumb）匯編程序所支持的變量有數(shù)字變量、邏輯變量和字符串變量。
數(shù)字變量用于在程序的運行中保存數(shù)字值，但注意數(shù)字值的大小不應(yīng)超出數(shù)字變量所能表示的范圍。
邏輯變量用于在程序的運行中保存邏輯值，邏輯值只有兩種取值情況：真或假。
字符串變量用于在程序的運行中保存一個字符串，但注意字符串的長度不應(yīng)超出字符串變量所能表示的范圍。
在ARM（Thumb）匯編語言程序設(shè)計中，可使用GBLA、GBLL、GBLS偽指令聲明全局變量，使用LCLA、LCLL、LCLS偽指令聲明局部變量，并可使用SETA、SETL和SETS對其進(jìn)行初始化。
2、 程序中的常量
程序中的常量是指其值在程序的運行過程中不能被改變的量。ARM（Thumb）匯編程序所支持的常量有數(shù)字常量、邏輯常量和字符串常量。
數(shù)字常量一般為32位的整數(shù)，當(dāng)作為無符號數(shù)時，其取值范圍為0～232-1，當(dāng)作為有符號數(shù)時，其取值范圍為-231～231-1。
邏輯常量只有兩種取值情況：真或假。
字符串常量為一個固定的字符串，一般用于程序運行時的信息提示。
3、 程序中的變量代換
程序中的變量可通過代換操作取得一個常量。代換操作符為“$”。
如果在數(shù)字變量前面有一個代換操作符“$”，編譯器會將該數(shù)字變量的值轉(zhuǎn)換為十六進(jìn)制的字符串，并將該十六進(jìn)制的字符串代換“$”后的數(shù)字變量。
如果在邏輯變量前面有一個代換操作符“$”，編譯器會將該邏輯變量代換為它的取值（真或假）。
如果在字符串變量前面有一個代換操作符“$”，編譯器會將該字符串變量的值代換“$”后的字符串變量。
使用示例：
LCLS S1 ；定義局部字符串變量S1和S2
LCLS S2
S1 SETS “Test！”
S2 SETS “This is a $S1” ；字符串變量S2的值為“This is a Test！”
4.2.2匯編語言程序中的表達(dá)式和運算符
在匯編語言程序設(shè)計中，也經(jīng)常使用各種表達(dá)式，表達(dá)式一般由變量、常量、運算符和括號構(gòu)成。常用的表達(dá)式有數(shù)字表達(dá)式、邏輯表達(dá)式和字符串表達(dá)式，其運算次序遵循如下的優(yōu)先級：
— 優(yōu)先級相同的雙目運算符的運算順序為從左到右。
— 相鄰的單目運算符的運算順序為從右到左，且單目運算符的優(yōu)先級高于其他運算符。
— 括號運算符的優(yōu)先級最高。
1、 數(shù)字表達(dá)式及運算符
數(shù)字表達(dá)式一般由數(shù)字常量、數(shù)字變量、數(shù)字運算符和括號構(gòu)成。與數(shù)字表達(dá)式相關(guān)的運算符如下：
— “＋”、“－”、“×”、“/” 及“MOD”算術(shù)運算符
以上的算術(shù)運算符分別代表加、減、乘、除和取余數(shù)運算。例如，以X和Y表示兩個數(shù)字表達(dá)式，則：
X＋Y 表示X與Y的和。
X－Y 表示X與Y的差。
X×Y 表示X與Y的乘積。
X/Y 表示X除以Y的商。
X：MOD：Y 表示X除以Y的余數(shù)。
— “ROL”、“ROR”、“SHL”及“SHR”移位運算符
以X和Y表示兩個數(shù)字表達(dá)式，以上的移位運算符代表的運算如下：
X：ROL：Y 表示將X循環(huán)左移Y位。
X：ROR：Y 表示將X循環(huán)右移Y位。
X：SHL：Y 表示將X左移Y位。
X：SHR：Y 表示將X右移Y位。
— “AND”、“OR”、“NOT”及“EOR”按位邏輯運算符
以X和Y表示兩個數(shù)字表達(dá)式，以上的按位邏輯運算符代表的運算如下：
X：AND：Y 表示將X和Y按位作邏輯與的操作。
X：OR：Y 表示將X和Y按位作邏輯或的操作。
：NOT：Y 表示將Y按位作邏輯非的操作。
X：EOR：Y 表示將X和Y按位作邏輯異或的操作。
2、 邏輯表達(dá)式及運算符
邏輯表達(dá)式一般由邏輯量、邏輯運算符和括號構(gòu)成，其表達(dá)式的運算結(jié)果為真或假。與邏輯表達(dá)式相關(guān)的運算符如下：
— “=”、“>”、“<”、“>=”、“<= ”、“/=”、“ <>” 運算符
以X和Y表示兩個邏輯表達(dá)式，以上的運算符代表的運算如下：
X = Y 表示X等于Y。
X > Y 表示X大于Y。
X < Y 表示X小于Y。
X >= Y 表示X大于等于Y。
X <= Y 表示X小于等于Y。
X /= Y 表示X不等于Y。
X <> Y 表示X不等于Y。
— “LAND”、“LOR”、“LNOT”及“LEOR”運算符
以X和Y表示兩個邏輯表達(dá)式，以上的邏輯運算符代表的運算如下：
X：LAND：Y 表示將X和Y 作邏輯與的操作。
X：LOR：Y 表示將X和Y作邏輯或的操作。
：LNOT：Y 表示將Y作邏輯非的操作。
X：LEOR：Y 表示將X和Y作邏輯異或的操作。
3、 字符串表達(dá)式及運算符
字符串表達(dá)式一般由字符串常量、字符串變量、運算符和括號構(gòu)成。編譯器所支持的字符串最大長度為512字節(jié)。常用的與字符串表達(dá)式相關(guān)的運算符如下：
— LEN運算符
LEN運算符返回字符串的長度（字符數(shù)），以X表示字符串表達(dá)式，其語法格式如下：
：LEN：X
— CHR運算符
CHR運算符將0～255之間的整數(shù)轉(zhuǎn)換為一個字符，以M表示某一個整數(shù)，其語法格式如下：
：CHR：M
— STR運算符
STR運算符將將一個數(shù)字表達(dá)式或邏輯表達(dá)式轉(zhuǎn)換為一個字符串。對于數(shù)字表達(dá)式，STR運算符將其轉(zhuǎn)換為一個以十六進(jìn)制組成的字符串；對于邏輯表達(dá)式，STR運算符將其轉(zhuǎn)換為字符串T或F，其語法格式如下：
：STR：X
其中，X為一個數(shù)字表達(dá)式或邏輯表達(dá)式。
— LEFT運算符
LEFT運算符返回某個字符串左端的一個子串，其語法格式如下：
X：LEFT：Y
其中：X為源字符串，Y為一個整數(shù)，表示要返回的字符個數(shù)。
— RIGHT運算符
與LEFT運算符相對應(yīng)，RIGHT運算符返回某個字符串右端的一個子串，其語法格式如下：
X：RIGHT：Y
其中：X為源字符串，Y為一個整數(shù)，表示要返回的字符個數(shù)。
— CC運算符
CC運算符用于將兩個字符串連接成一個字符串，其語法格式如下：
X：CC：Y
其中：X為源字符串1，Y為源字符串2，CC運算符將Y連接到X的后面。
4、 與寄存器和程序計數(shù)器（PC）相關(guān)的表達(dá)式及運算符
常用的與寄存器和程序計數(shù)器（PC）相關(guān)的表達(dá)式及運算符如下：
— BASE運算符
BASE運算符返回基于寄存器的表達(dá)式中寄存器的編號，其語法格式如下：
：BASE：X
其中，X為與寄存器相關(guān)的表達(dá)式。
— INDEX運算符
INDEX運算符返回基于寄存器的表達(dá)式中相對于其基址寄存器的偏移量，其語法格式如下：
：INDEX：X
其中，X為與寄存器相關(guān)的表達(dá)式。
5、 其他常用運算符
—？運算符
？運算符返回某代碼行所生成的可執(zhí)行代碼的長度，例如：
?X
返回定義符號X的代碼行所生成的可執(zhí)行代碼的字節(jié)數(shù)。
— DEF運算符
DEF運算符判斷是否定義某個符號，例如：
：DEF：X
如果符號X已經(jīng)定義，則結(jié)果為真，否則為假。
4.3匯編語言的程序結(jié)構(gòu)
4.3.1匯編語言的程序結(jié)構(gòu)
在ARM（Thumb）匯編語言程序中，以程序段為單位組織代碼。段是相對獨立的指令或數(shù)據(jù)序列，具有特定的名稱。段可以分為代碼段和數(shù)據(jù)段，代碼段的內(nèi)容為執(zhí)行代碼，數(shù)據(jù)段存放代碼運行時需要用到的數(shù)據(jù)。一個匯編程序至少應(yīng)該有一個代碼段，當(dāng)程序較長時，可以分割為多個代碼段和數(shù)據(jù)段，多個段在程序編譯鏈接時最終形成一個可執(zhí)行的映象文件。
可執(zhí)行映象文件通常由以下幾部分構(gòu)成：
—一個或多個代碼段，代碼段的屬性為只讀。
— 零個或多個包含初始化數(shù)據(jù)的數(shù)據(jù)段，數(shù)據(jù)段的屬性為可讀寫。
—零個或多個不包含初始化數(shù)據(jù)的數(shù)據(jù)段，數(shù)據(jù)段的屬性為可讀寫。
鏈接器根據(jù)系統(tǒng)默認(rèn)或用戶設(shè)定的規(guī)則，將各個段安排在存儲器中的相應(yīng)位置。因此源程序中段之間的相對位置與可執(zhí)行的映象文件中段的相對位置一般不會相同。
以下是一個匯編語言源程序的基本結(jié)構(gòu)：
AREA Init，CODE，READONLY
ENTRY
Start
LDR R0，=0x3FF5000
LDR R1，0xFF
STR R1，[R0]
LDR R0，=0x3FF5008
LDR R1，0x01
STR R1，[R0]
┉┉
END
在匯編語言程序中，用AREA偽指令定義一個段，并說明所定義段的相關(guān)屬性，本例定義一個名為Init的代碼段，屬性為只讀。ENTRY偽指令標(biāo)識程序的入口點，接下來為指令序列，程序的末尾為END偽指令，該偽指令告訴編譯器源文件的結(jié)束，每一個匯編程序段都必須有一條END偽指令，指示代碼段的結(jié)束。
4.3.2匯編語言的子程序調(diào)用
在ARM匯編語言程序中，子程序的調(diào)用一般是通過BL指令來實現(xiàn)的。在程序中，使用指令：BL子程序名
即可完成子程序的調(diào)用。
該指令在執(zhí)行時完成如下操作：將子程序的返回地址存放在連接寄存器LR中，同時將程序計數(shù)器PC指向子程序的入口點，當(dāng)子程序執(zhí)行完畢需要返回調(diào)用處時，只需要將存放在LR中的返回地址重新拷貝給程序計數(shù)器PC即可。在調(diào)用子程序的同時，也可以完成參數(shù)的傳遞和從子程序返回運算的結(jié)果，通?？梢允褂眉拇嫫鱎0～R3完成。
以下是使用BL指令調(diào)用子程序的匯編語言源程序的基本結(jié)構(gòu)：
AREA Init，CODE，READONLY
ENTRY
Start
LDR R0，=0x3FF5000
LDR R1，0xFF
STR R1，[R0]
LDR R0，=0x3FF5008
LDR R1，0x01
STR R1，[R0]
BL PRINT_TEXT
┉┉
PRINT_TEXT
┉┉
MOV PC，BL
┉┉
END
4.3.3匯編語言程序示例
以下是一個基于S3C4510B的串行通訊程序，關(guān)于S3C4510B的串行通訊的工作原理，可以參考第六章的相關(guān)內(nèi)容，在此僅向讀者說明一個完整匯編語言程序的基本結(jié)構(gòu)：
;
; Institute of Automation,Chinese Academy of Sciences
;Description: This example shows the UART communication！
;Author: JuGuang,Lee
;Date:
;
UARTLCON0 EQU 0x3FFD000
UARTCONT0 EQU 0x3FFD004
UARTSTAT0 EQU 0x3FFD008
UTXBUF0 EQU 0x3FFD00C
UARTBRD0 EQU 0x3FFD014
AREA Init,CODE,READONLY
ENTRY
;
;LED Display
;
LDR R1,=0x3FF5000
LDR R0,=&ff
STR R0,[R1]
LDR R1,=0x3FF5008
LDR R0,=&ff
STR R0,[R1]
;*
;UART0 line control register
;*
LDR R1,=UARTLCON0
LDR R0,=0x03
STR R0,[R1]
;
;UART0 control regiser
;
LDR R1,=UARTCONT0
LDR R0,=0x9
STR R0,[R1]
;
;UART0 baud rate divisor regiser
;Baudrate=19200，對應(yīng)于50MHz的系統(tǒng)工作頻率
;*
LDR R1,=UARTBRD0
LDR R0,=0x500
STR R0,[R1]
;*
;Print the messages!
;*
LOOP
LDR R0,=Line1
BL PrintLine
LDR R0,=Line2
BL PrintLine
LDR R0,=Line3
BL PrintLine
LDR R0,=Line4
BL PrintLine
LDR R1,=0x7FFFFF
LOOP1
SUBS R1,R1,#1
BNE LOOP1
B LOOP
;*
;Print line
;*
PrintLine
MOV R4,LR
MOV R5,R0
Line
LDRB R1,[R5],#1
AND R0,R1,#&FF
TST R0,#&FF
MOVEQ PC,R4
BL PutByte
B Line
PutByte
LDR R3,=UARTSTAT0
LDR R2,[R3]
TST R2,#&40
BEQ PutByte
LDR R3,=UTXBUF0
STR R0,[R3]
MOV PC,LR
Line1 DCB &A,&D,"",0
Line2 DCB &A,&D,"Chinese Academy of Sciences,Institute of Automation,Complex System Lab.",0
Line3 DCB &A,&D," ARM Development Board Based on Samsung ARM S3C4510B.",0
Line4 DCB &A,&D,&A,&D,&A,&D,&A,&D,&A,&D,&A,&D,&A,&D,&A,&D,&A,&D,&A,&D,&A,&D,&A,&D,&A,&D,&A,&D,&A,&D,0
END
4.3.4匯編語言與C/C++的混合編程
在應(yīng)用系統(tǒng)的程序設(shè)計中，若所有的編程任務(wù)均用匯編語言來完成，其工作量是可想而知的，同時，不利于系統(tǒng)升級或應(yīng)用軟件移植，事實上，ARM體系結(jié)構(gòu)支持C/C＋以及與匯編語言的混合編程，在一個完整的程序設(shè)計的中，除了初始化部分用匯編語言完成以外，其主要的編程任務(wù)一般都用C/C++ 完成。
匯編語言與C/C++的混合編程通常有以下幾種方式：
－ 在C/C＋＋代碼中嵌入匯編指令。
－ 在匯編程序和C/C＋＋的程序之間進(jìn)行變量的互訪。
－ 匯編程序、C/C＋＋程序間的相互調(diào)用。
在以上的幾種混合編程技術(shù)中，必須遵守一定的調(diào)用規(guī)則，如物理寄存器的使用、參數(shù)的傳遞等，這對于初學(xué)者來說，無疑顯得過于煩瑣。在實際的編程應(yīng)用中，使用較多的方式是：程序的初始化部分用匯編語言完成，然后用C/C＋＋完成主要的編程任務(wù)，程序在執(zhí)行時首先完成初始化過程，然后跳轉(zhuǎn)到C/C＋＋程序代碼中，匯編程序和C/C＋＋程序之間一般沒有參數(shù)的傳遞，也沒有頻繁的相互調(diào)用，因此，整個程序的結(jié)構(gòu)顯得相對簡單，容易理解。以下是一個這種結(jié)構(gòu)程序的基本示例，該程序基于第五、六章所描述的硬件平臺：
;*
; Institute of Automation, Chinese Academy of Sciences
;File Name: Init.s
;Description:
;Author: JuGuang,Lee
;Date:
;
IMPORT Main ;通知編譯器該標(biāo)號為一個外部標(biāo)號
AREA Init,CODE,READONLY ；定義一個代碼段
ENTRY ；定義程序的入口點
LDR R0,=0x3FF0000 ；初始化系統(tǒng)配置寄存器，具體內(nèi)容可參考第五、六章
LDR R1,=0xE7FFFF80
STR R1,[R0]
LDR SP,=0x3FE1000 ；初始化用戶堆棧，具體內(nèi)容可參考第五、六章
BL Main ；跳轉(zhuǎn)到Main（）函數(shù)處的C/C++代碼執(zhí)行
END ；標(biāo)識匯編程序的結(jié)束
以上的程序段完成一些簡單的初始化，然后跳轉(zhuǎn)到Main（）函數(shù)所標(biāo)識的C/C＋＋代碼處執(zhí)行主要的任務(wù)，此處的Main僅為一個標(biāo)號，也可使用其他名稱，與C語言程序中的main（）函數(shù)沒有關(guān)系。
/*
* Institute of Automation, Chinese Academy of Sciences
* File Name: main.c
* Description: P0,P1 LED flash.
* Author: JuGuang,Lee
* Date:
/
void Main(void)
{
int i;
*((volatile unsigned long *) 0x3ff5000) = 0x0000000f;
while(1)
{
*((volatile unsigned long *) 0x3ff5008) = 0x00000001;
for(i=0; i<0x7fFFF; i++);
*((volatile unsigned long *) 0x3ff5008) = 0x00000002;
for(i=0; i<0x7FFFF; i++);
}
}
4.4本章小節(jié)
4.4本章小節(jié)
本章介紹了ARM程序設(shè)計的一些基本概念，以及在匯編語言程序設(shè)計中常見的偽指令、匯編語言的基本語句格式等，匯編語言程序的基本結(jié)構(gòu)等，同時簡單介紹了C/C＋＋和匯編語言的混合編程等問題，這些問題均為程序設(shè)計中的基本問題，希望讀者掌握，注意本章最后的兩個示例均與后面章節(jié)介紹的基于S3C4510B的硬件平臺有關(guān)系，讀者可以參考第五、六章的相關(guān)內(nèi)容。
評論