ARM匯編中的LDR及ADR的區(qū)別及其在UBOOT中的應(yīng)用

lowlevel_init:
ldr r0, =SMRDATA
ldr r1, _TEXT_BASE
sub r0, r0, r1
ldr r1, =BWSCON
add r2, r0, #13*4
0:
ldr r3, [r0], #4
str r3, [r1], #4
cmp r2, r0
bne 0b
mov pc, lr

這段代碼實(shí)現(xiàn)了U-BOOT的內(nèi)存控制器部分的寄存器初始化，一共13個(gè)寄存器，對(duì)U-BOOT來(lái)最重要的就是SDRAM的初始化，顯然沒(méi)有這部分代碼，當(dāng)U-BOOT從NAND FLASH中啟動(dòng)的時(shí)候，START.S文件是無(wú)法完成代碼的relocate的。因?yàn)镾DRAM沒(méi)初始化,用不了。

要理解這段代碼主要是搞清楚LDR的兩種用法。

ldr r0, =SMRDATA的作用是讓r0等于U-BOOT編譯時(shí)已經(jīng)確定下來(lái)的SMRDATA這塊內(nèi)存緩沖池的起始地址。
ldr r1, _TEXT_BASE的作用則是讓r1等于_TEXT_BASE這個(gè)標(biāo)號(hào)所在的內(nèi)存里面的內(nèi)容，也就是 TEXT_BASE。對(duì)于MINI2440開(kāi)發(fā)板來(lái)說(shuō)這個(gè)值等于 TEXT_BASE = 0x33F80000（boardsamsungmini2440config.mk）這個(gè)地址是
由于TEXT_BASE實(shí)際的地址現(xiàn)在應(yīng)該是FLASH的0地址(或者內(nèi)部4KSRAM的0地址)，所以第三條指令 sub r0, r0, r1 ，實(shí)現(xiàn)了計(jì)算SMRDATA當(dāng)前在arm地址空間里的實(shí)際訪問(wèn)地址。
接下去就是通過(guò)
ldr r3, [r0], #4 ；從r0這個(gè)地址里取一個(gè)32bit的數(shù)據(jù)，放到r3,并將r0+4，指向下一個(gè)內(nèi)存池里的數(shù)據(jù)。
str r3, [r1], #4 ；這條指令實(shí)現(xiàn)了把r3里的數(shù)據(jù)賦值給r1所標(biāo)示的地址。r1的地址通過(guò)下面這幾句實(shí)現(xiàn)。以此配置完從0x48000000開(kāi)始的CPU內(nèi)部寄存器的值。這樣SDRAM就開(kāi)始工作了。以后就是正常訪問(wèn)0x30000000開(kāi)始的地址空間了。
#define BWSCON 0x48000000
ldr r1, =BWSCON /* Bus Width Status Controller */
上面的這個(gè)配置代碼是無(wú)法在將U-BOOT直接用OPENJTAG下載到OPENJTAG中時(shí)工作的。因?yàn)楫?dāng)下載到內(nèi)存中的時(shí)候，SDRAM的地址是隨機(jī)的，至少不是從0開(kāi)始的，這樣得到的SMRDATA所在的地址按上面的方式是得不到的，所以需要一條在運(yùn)行時(shí)地址與位置無(wú)關(guān)的指令。這就是 adr指令。下面代碼就是改進(jìn)后的：
lowlevel_init:
/* memory control configuration */
/* make r0 relative the current location so that it */
/* reads SMRDATA out of FLASH rather than memory ! */
ldr r0, =SMRDATA
ldr r1, =lowlevel_init /*編譯時(shí)確定的地址*/
sub r0, r0, r1 /* r0 = r0 -r1 , r0 = SMRDATA相對(duì)于lowlevel_init的偏移值 */
adr r3, lowlevel_init /*位置無(wú)關(guān)*/
add r0,r0,r3 /*r0 = r0 +r3 ，r0存放的是當(dāng)前SMRDATA的實(shí)際地址*/
ldr r1, =BWSCON /* Bus Width Status Controller */
add r2, r0, #13*4
0:
ldr r3, [r0], #4
str r3, [r1], #4
cmp r2, r0
bne 0b